Fix #689, false negatives for A1-1-2 thinking -Wno-foo is compliant.

change_notes/2024-09-18-handle-warning-suppresion-flags

@@ -0,0 +1,2 @@
+- `A1-1-2` - `CompilerWarningLevelNotInCompliance.ql`:
+  - Fixes #689 false negatives where '-Wno-foo' was treated as enabling, rather than disabling warnings.

cpp/autosar/src/rules/A1-1-2/CompilerWarningLevelNotInCompliance.ql

@@ -20,13 +20,56 @@ import codingstandards.cpp.autosar
 
 predicate hasResponseFileArgument(Compilation c) { c.getAnArgument().matches("@%") }
 
-predicate hasWarningOption(Compilation c) { c.getAnArgument().regexpMatch("-W[\\w=-]+") }
+class CompilationArgument extends string {
+  Compilation compilation;
+
+  CompilationArgument() { this = compilation.getAnArgument() }
+}
+
+/**
+ * Compiler flags of type -Wfoo or -Wfoo=bar, which enables the `foo` warning.
+ */
+class EnableWarningFlag extends CompilationArgument {
+  string warningType;
+
+  EnableWarningFlag() {
+    warningType = regexpCapture("^-W([\\w-]+)(=.*)?$", 1) and
+    not this instanceof DisableWarningFlag
+  }
+
+  string getWarningType() { result = warningType }
+}
+
+/**
+ * Compiler flags of type -Wno-foo or -Wfoo=0, which disables the `foo` warning
+ * and overrules -Wfoo.
+ */
+class DisableWarningFlag extends CompilationArgument {
+  string warningType;
+
+  DisableWarningFlag() {
+    warningType = regexpCapture("^-Wno-([\\w-]+)", 1) or
+    warningType = regexpCapture("^-W([\\w-]+)=0", 1)
+  }
+
+  string getWarningType() { result = warningType }
+}
+
+predicate hasEnabledWarning(Compilation c) {
+  exists(EnableWarningFlag enableFlag |
+    c.getAnArgument() = enableFlag and
+    not exists(DisableWarningFlag disableFlag |
+      c.getAnArgument() = disableFlag and
+      enableFlag.getWarningType() = disableFlag.getWarningType()
+    )
+  )
+}
 
 from File f
 where
   not isExcluded(f, ToolchainPackage::compilerWarningLevelNotInComplianceQuery()) and
   exists(Compilation c | f = c.getAFileCompiled() |
     not hasResponseFileArgument(c) and
-    not hasWarningOption(c)
+    not hasEnabledWarning(c)
   )
 select f, "No warning-level options were used in the compilation of '" + f.getBaseName() + "'."

cpp/autosar/test/rules/A1-1-2.4/CompilerWarningLevelNotInCompliance.expected

@@ -0,0 +1 @@
+| Wformat=0-Wno-format-security.cpp:0:0:0:0 | Wformat=0-Wno-format-security.cpp | No warning-level options were used in the compilation of 'Wformat=0-Wno-format-security.cpp'. |

cpp/autosar/test/rules/A1-1-2.4/CompilerWarningLevelNotInCompliance.qlref

@@ -0,0 +1 @@
+rules/A1-1-2/CompilerWarningLevelNotInCompliance.ql

cpp/autosar/test/rules/A1-1-2.4/Wformat=0-Wno-format-security.cpp

@@ -0,0 +1,2 @@
+// semmle-extractor-options: --clang -std=c++14 -Wformat=0 -Wno-format-security
+// NON_COMPLIANT

cpp/autosar/test/rules/A1-1-2.4/options.clang

@@ -0,0 +1 @@
+-Wformat=0 -Wno-format-security

cpp/autosar/test/rules/A1-1-2.4/options.gcc

@@ -0,0 +1 @@
+-Wformat=0 -Wno-format-security

cpp/autosar/test/rules/A1-1-2.4/options.qcc

@@ -0,0 +1 @@
+-Wno-format -Wno-format-security

cpp/autosar/test/rules/A1-1-2.5/CompilerWarningLevelNotInCompliance.qlref

@@ -0,0 +1 @@
+rules/A1-1-2/CompilerWarningLevelNotInCompliance.ql

cpp/autosar/test/rules/A1-1-2.5/Wall-Wno-format.cpp

@@ -0,0 +1,2 @@
+// semmle-extractor-options: --clang -std=c++14 -Wall -Wno-format
+// COMPLIANT

cpp/autosar/test/rules/A1-1-2.5/options.clang

@@ -0,0 +1 @@
+-Wall -Wno-format

cpp/autosar/test/rules/A1-1-2.5/options.gcc

@@ -0,0 +1 @@
+-Wall -Wno-format

cpp/autosar/test/rules/A1-1-2.5/options.qcc

@@ -0,0 +1 @@
+-Wall -Wno-format